/* -------------------------------------------------------------------------- */
/*  GRAPHRAT.GPG graphs ratios of components to GNP, to find stationary ones  */
/*  load data in aerppr.gpg first.                                            */
/*
    index to graphs:
    fig1.tkf = VAR GNP, consumption            part2.gpg
    fig2.tkf = univariate GNP consumption      part3.gpg
    fig3.tkf = spectral, GNP                   aerppr.gpg
    fig4.tkf = GNP ratios                      graphrat.gpg
    fig5.tkf = private GNP var                 part2.gpg
    fig6.tkf = private GNP univariate          part3.gpg
    fig7.tkf = stock var                       part2.gpg
    fig8.tkf = stock univariate                part3.gpg
    fig9.tkf = stock ratio                     aerppr.gpg
    fig10.tkf = bn trend                       aerppr.gpg
    fig11.tkf = bn big trend                   aerppr.gpg
    fig12.tkf = labor income var               part2.gpg
    fig13.tkf = labor income univariate        part3.gpg
    fig14.tkf = labor income spectral          aerppr.gpg

*/
/* -------------------------------------------------------------------------- */

     load x[171,11] = gene.dat;
     YEAR    =x[.,1];
     QUARTER =x[.,2];
     GCD82   =x[.,3];
     GCN82   =x[.,4];
     GCS82   =x[.,5];
     GGE82   =x[.,6];
     GIF82   =x[.,7];
     GIN82   =x[.,8];
     GIR82   =x[.,9];
     GNP82   =x[.,10];
     GPI82   =x[.,11];
     gcns82 = gcn82+gcs82;
     ti     = gpi82+gcd82;

         load x[171,7] = income.dat;
         GPDIV = x[.,3];       /* dividends       */
         GPINT = x[.,4];       /* interest        */
         GPRENJ= x[.,5];       /* rent            */
         GYD   = x[.,6];       /* pers disp. inc. */
         GYD82 = x[.,7];       /* pdi in 82$      */

         labinc = gyd82 - (gpdiv+gpint+gprenj).*gyd82./gyd;


library pgraph;
graphset;
px = seqa(47,.25,rows(gnp82));
_Pltype = 6;
ytics(.45,1.05,.1,0);
_Pmsgstr = "C/GNP\000C/Private GNP\000C/labor income";
/*            x   y height(in) angle plot=0/in=1 color                      */
 _Pmsgctl = ( 55 ~ .57 ~ .15     ~ 0   ~   0       ~ 10 )|
            ( 55 ~ .77~ .15     ~ 0   ~   0       ~ 10 )|
            ( 55 ~ 1.00 ~ .15     ~ 0   ~   0       ~ 10 );

_Pmsgstr = _Pmsgstr $+
"\000Fig. 4. Consumption/GNP, consumption/private GNP and "
$+
"\000        consumption/labor income ratios.";
_Pmsgctl = _Pmsgctl|
               /*  x y ht 0 0 10 */
                (1.7~6.7 ~.11~0~1~10)|
                (1.7~6.5 ~.11~0~1~10);
_Ptek = "fig4.tkf";
xlabel("Date");
ylabel("Ratio");
xy(px,(gcns82./gnp82)~(gcns82./(GNp82-GGE82))~(gcns82./labinc));